HDLBits刷题之旅鼠冲冲冲

前言

百战小旅鼠1991年由DMA Design（今rockstar north，蓝R）开发。

旅鼠会左右走，还会挖洞。如果下落太久了还会摔得四分五裂~~坠机了~~

思路

七个状态：左右、下落左右、向下挖时原本朝向左右，以及四分五裂。

代码

module top_module (
    input  clk,
    input  areset,      // Freshly brainwashed Lemmings walk left.
    input  bump_left,
    input  bump_right,
    input  ground,
    input  dig,
    output walk_left,
    output walk_right,
    output aaah,
    output digging
);

    parameter LEFT = 0, RIGHT = 1, FALLING_LEFT = 2, FALLING_RIGHT = 3, DIGGING_LEFT = 4,
        DIGGING_RIGHT = 5, SPLAT = 6;
    reg [2:0] state, next_state;
    reg [7:0] count, next_count;

    always @(*) begin

        next_count = count;

        case (state)

            LEFT: begin
                if (!ground) begin
                    next_state = FALLING_LEFT;
                    next_count = 0;
                end
                else if (dig) next_state = DIGGING_LEFT;
                else if (bump_left) next_state = RIGHT;
                else next_state = LEFT;
            end

            RIGHT: begin
                if (!ground) begin
                    next_state = FALLING_RIGHT;
                    next_count = 0;
                end
                else if (dig) next_state = DIGGING_RIGHT;
                else if (bump_right) next_state = LEFT;
                else next_state = RIGHT;
            end

            FALLING_LEFT: begin
                if (ground) begin
                    if (count >= 20) begin
                        next_state = SPLAT;
                        next_count = count;
                    end
                    else begin
                        next_state = LEFT;
                        next_count = 0;
                    end
                end
                else begin
                    next_state = FALLING_LEFT;
                    next_count = count + 1;
                end
            end

            FALLING_RIGHT: begin
                if (ground) begin
                    if (count >= 20) begin
                        next_state = SPLAT;
                        next_count = count;
                    end
                    else begin
                        next_state = RIGHT;
                        next_count = 0;
                    end
                end
                else begin
                    next_state = FALLING_RIGHT;
                    next_count = count + 1;
                end
            end

            DIGGING_LEFT: begin
                if (ground) next_state = DIGGING_LEFT;
                else begin
                    next_state = FALLING_LEFT;
                    next_count = 0;
                end
            end

            DIGGING_RIGHT: begin
                if (ground) next_state = DIGGING_RIGHT;
                else begin
                    next_state = FALLING_RIGHT;
                    next_count = 0;
                end
            end

            SPLAT: next_state = SPLAT;

            default: next_state = LEFT;

        endcase
    end

    always @(posedge clk, posedge areset) begin
        if (areset) begin
            state <= LEFT;
            count <= 0;
        end
        else begin
            state <= next_state;
            count <= next_count;
        end
    end

    // assign aaah       = (state == FALLING_LEFT) || (state == FALLING_RIGHT);
    // assign digging    = (state == DIGGING_LEFT) || (state == DIGGING_RIGHT);
    // assign walk_left  = (state == LEFT);
    // assign walk_right = (state == RIGHT);

    assign {aaah, digging, walk_left, walk_right} = (state == SPLAT) ?
        4'b0000 : {{(state == FALLING_LEFT) || (state == FALLING_RIGHT)},
                   {(state == DIGGING_LEFT) || (state == DIGGING_RIGHT)},
                   {(state == LEFT)}, {(state == RIGHT)}};

endmodule